SConstruct

   1 #
   2 #       SConstruct (10.09.09)
   3 #       SConscript for all components.
   4 #
   5 #       Copyright (C) 2010-2013  Andrew Nayenko
   6 #
   7 #       This program is free software: you can redistribute it and/or modify
   8 #       it under the terms of the GNU General Public License as published by
   9 #       the Free Software Foundation, either version 3 of the License, or
  10 #       (at your option) any later version.
  11 #
  12 #       This program is distributed in the hope that it will be useful,
  13 #       but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #       MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #       GNU General Public License for more details.
  16 #
  17 #       You should have received a copy of the GNU General Public License
  18 #       along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21 import os
  22 import platform
  23 import SCons
  24
  25 env = Environment(**ARGUMENTS)
  26 for var in ['PATH', 'SYSROOT']:
  27         if var in os.environ:
  28                 env['ENV'][var] = os.environ[var]
  29
  30 destdir = env.get('DESTDIR', '/sbin');
  31 libs = ['exfat']
  32 libfuse = 'fuse'
  33
  34 if not env.GetOption('clean'):
  35         conf = Configure(env)
  36
  37         if 'AR' in os.environ:
  38                 conf.env.Replace(AR = os.environ['AR'])
  39         if 'RANLIB' in os.environ:
  40                 conf.env.Replace(RANLIB = os.environ['RANLIB'])
  41         if 'CC' in os.environ:
  42                 conf.env.Replace(CC = os.environ['CC'])
  43         if 'CCFLAGS' in os.environ:
  44                 conf.env.Replace(CCFLAGS = os.environ['CCFLAGS'])
  45         # Set default CCFLAGS for known compilers
  46         if not conf.env['CCFLAGS']:
  47                 if conf.env['CC'] == 'gcc':
  48                         conf.env.Replace(CCFLAGS = '-Wall -O2 -ggdb -std=c99')
  49                 elif conf.env['CC'] == 'clang':
  50                         conf.env.Replace(CCFLAGS = '-Wall -O2 -g -std=c99')
  51         if 'CPPFLAGS' in os.environ:
  52                 conf.env.Replace(CPPFLAGS = os.environ['CPPFLAGS'])
  53         conf.env.Append(CPPDEFINES = {'_FILE_OFFSET_BITS' : 64})
  54         conf.env.Append(CPPPATH = ['libexfat'])
  55         if 'LDFLAGS' in os.environ:
  56                 conf.env.Append(LINKFLAGS = os.environ['LDFLAGS'])
  57         conf.env.Append(LIBPATH = ['libexfat'])
  58
  59         # GNU/Linux requires _BSD_SOURCE define for vsyslog(), _XOPEN_SOURCE >= 500
  60         # for pread(), pwrite(), snprintf(), strdup(), etc. Everything needed is
  61         # enabled by _GNU_SOURCE.
  62         if platform.system() == 'Linux':
  63                 conf.env.Append(CPPDEFINES = '_GNU_SOURCE');
  64
  65         # Use 64-bit inode numbers (introduced in Mac OS X 10.5 Leopard). Require
  66         # OSXFUSE (http://osxfuse.github.com).
  67         if platform.system() == 'Darwin':
  68                 conf.env.Append(CPPDEFINES = '_DARWIN_USE_64_BIT_INODE')
  69                 conf.env.Append(CPPDEFINES = {'__DARWIN_UNIX03' : 1})
  70                 conf.env.Append(CPPPATH = ['/usr/local/include/osxfuse'])
  71                 conf.env.Append(CFLAGS    = '-mmacosx-version-min=10.5')
  72                 conf.env.Append(LINKFLAGS = '-mmacosx-version-min=10.5')
  73                 libfuse = 'osxfuse_i64'
  74
  75         # FreeBSD does not support block devices, only raw devices. Ublio is
  76         # required for unaligned I/O and caching.
  77         if platform.system() == 'FreeBSD':
  78                 conf.env.Append(CPPDEFINES = 'USE_UBLIO')
  79                 libs.append('ublio')
  80                 conf.env.Append(CPPPATH = ['/usr/local/include'])
  81                 conf.env.Append(LIBPATH = ['/usr/local/lib'])
  82
  83         if not conf.CheckCC():
  84                 print '''
  85         A working C compiler is needed very much.
  86 '''
  87                 Exit(1)
  88
  89         if not conf.CheckTypeSize('off_t', '#include <sys/types.h>', 'C', 8):
  90                 print '''
  91         The size of off_t type must be 64 bits. File systems larger than
  92         2 GB will be corrupted with 32-bit off_t.
  93 '''
  94                 Exit(1)
  95
  96         env = conf.Finish()
  97
  98
  99
 100 def make_symlink(dir, target, link_name):
 101         workdir = os.getcwd()
 102         os.chdir(dir)
 103         try:
 104                 os.remove(link_name)
 105         except OSError:
 106                 pass
 107         os.symlink(target, link_name)
 108         os.chdir(workdir)
 109
 110 symlink = SCons.Action.ActionFactory(make_symlink,
 111                 lambda dir, target, link_name:
 112                                 'make_symlink("%s", "%s", "%s")' % (dir, target, link_name))
 113
 114 def program(pattern, output, alias, libs):
 115         sources = Glob(pattern)
 116         if not sources:
 117                 return
 118         target = env.Program(output, sources, LIBS = libs)
 119         if alias:
 120                 Clean(Alias('install', Install(destdir, target),
 121                                 symlink(destdir, os.path.basename(output), alias)),
 122                                 destdir + '/' + alias)
 123         else:
 124                 Alias('install', Install(destdir, target))
 125
 126 env.Library('libexfat/exfat', Glob('libexfat/*.c'))
 127
 128 program('fuse/*.c', 'fuse/mount.exfat-fuse', 'mount.exfat', [libs + [libfuse]])
 129 program('dump/*.c', 'dump/dumpexfat', None, libs)
 130 program('fsck/*.c', 'fsck/exfatfsck', 'fsck.exfat', libs)
 131 program('mkfs/*.c', 'mkfs/mkexfatfs', 'mkfs.exfat', libs)
 132 program('label/*.c', 'label/exfatlabel', None, libs)