vym.pro

   1 TARGET      = vym
   2 TEMPLATE    = app
   3 LANGUAGE    = C++
   4
   5 CONFIG  += qt warn_on x86_64
   6
   7 QMAKE_MAC_SDK = macosx10.10
   8
   9 QT += network
  10 QT += xml
  11 QT += svg
  12 QT += printsupport
  13
  14 QT += widgets
  15
  16 #  include(tmp/modeltest/modeltest.pri)
  17
  18 RESOURCES = vym.qrc
  19
  20 unix:!macx:isEmpty(NO_DBUS) {
  21     message("Compiling with DBUS")
  22     DEFINES += VYM_DBUS
  23     QT      += dbus
  24     HEADERS += adaptormodel.h adaptorvym.h
  25     SOURCES += adaptormodel.cpp adaptorvym.cpp
  26 }
  27
  28 win32 {
  29     HEADERS += mkdtemp.h
  30     SOURCES += mkdtemp.cpp
  31     RC_FILE = vym.rc
  32     # Manifest embedding was suggested by Qt docs somewhere...
  33     win32: CONFIG += embed_manifest_exe
  34
  35     # Without this, M_PI, and M_PI_2 won`t be defined.
  36     win32:DEFINES *= _USE_MATH_DEFINES
  37
  38     QT_QPA_PLATFORM_PLUGIN_PATH=%QTDIR%\plugins\platforms\
  39 }
  40 macx {
  41     QMAK_MAC_SDK = macosx10.10
  42     QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.10
  43 }
  44
  45 TRANSLATIONS += lang/vym.de_DE.ts
  46 TRANSLATIONS += lang/vym.el.ts
  47 TRANSLATIONS += lang/vym.en.ts
  48 TRANSLATIONS += lang/vym.es.ts
  49 TRANSLATIONS += lang/vym.fr.ts
  50 TRANSLATIONS += lang/vym.hr_HR.ts
  51 TRANSLATIONS += lang/vym.ia.ts
  52 TRANSLATIONS += lang/vym.it.ts
  53 TRANSLATIONS += lang/vym.ja.ts
  54 TRANSLATIONS += lang/vym.pt_BR.ts
  55 TRANSLATIONS += lang/vym.ru.ts
  56 TRANSLATIONS += lang/vym.sv.ts
  57 TRANSLATIONS += lang/vym.zh_CN.ts
  58 TRANSLATIONS += lang/vym.zh_TW.ts
  59 TRANSLATIONS += lang/vym.cs_CZ.ts
  60
  61 ICON =icons/vym.icns
  62
  63
  64 HEADERS += \
  65     aboutdialog.h \
  66     taskfiltermodel.h \
  67     animpoint.h \
  68     arrowobj.h \
  69     attribute.h \
  70     attributeitem.h \
  71 #   attributedelegate.h\
  72 #   attributedialog.h \
  73 #   attributewidget.h \
  74     branchitem.h \
  75     branchobj.h \
  76     branchpropeditor.h\
  77     bugagent.h \
  78     command.h \
  79     dockeditor.h \
  80     downloadagent.h \
  81     editxlinkdialog.h \
  82     exportoofiledialog.h \
  83     exporthtmldialog.h\
  84     exports.h \
  85     extrainfodialog.h \
  86     file.h \
  87     findwidget.h \
  88     findresultwidget.h \
  89     findresultitem.h \
  90     findresultmodel.h \
  91     flag.h \
  92     flagobj.h \
  93     flagrowobj.h \
  94     flagrow.h \
  95     floatimageobj.h \
  96     floatobj.h \
  97     frameobj.h \
  98     geometry.h \
  99     heading.h \
 100     headingeditor.h \
 101     headingobj.h \
 102     highlighter.h \
 103     historywindow.h \
 104     imageitem.h \
 105     imageobj.h \
 106     imports.h \
 107     lineeditdialog.h \
 108     linkablemapobj.h \
 109     lockedfiledialog.h \
 110     macros.h \
 111     mainwindow.h \
 112     mapeditor.h \
 113     mapitem.h \
 114     mapobj.h \
 115     misc.h \
 116     mysortfilterproxymodel.h \
 117     noteeditor.h \
 118     options.h \
 119     ornamentedobj.h \
 120     parser.h \
 121     scripteditor.h\
 122     settings.h \
 123     shortcuts.h\
 124     showtextdialog.h\
 125     slidecontrolwidget.h\
 126     slideeditor.h\
 127     slideitem.h\
 128     slidemodel.h\
 129     task.h\
 130     taskeditor.h\
 131     taskmodel.h\
 132     treedelegate.h \
 133     treeeditor.h \
 134     treeitem.h \
 135     treemodel.h \
 136     texteditor.h \
 137     version.h \
 138     vymlock.h \
 139     vymmodel.h \
 140     vymnote.h \
 141     vymprocess.h \
 142     vymtext.h \
 143     vymview.h \
 144     winter.h \
 145     warningdialog.h \
 146     xlink.h \
 147     xlinkitem.h \
 148     xlinkobj.h \
 149     xml-base.h \
 150     xml-vym.h \
 151     xml-freemind.h \
 152     xmlobj.h\
 153     xsltproc.h
 154
 155 SOURCES += \
 156     aboutdialog.cpp \
 157     taskfiltermodel.cpp \
 158     animpoint.cpp \
 159     arrowobj.cpp \
 160     attribute.cpp \
 161     attributeitem.cpp \
 162 #   attributedelegate.cpp \
 163 #   attributedialog.cpp \
 164 #   attributewidget.cpp \
 165     branchitem.cpp \
 166     branchobj.cpp \
 167     branchpropeditor.cpp \
 168     bugagent.cpp \
 169     command.cpp \
 170     dockeditor.cpp \
 171     downloadagent.cpp \
 172     editxlinkdialog.cpp \
 173     exportoofiledialog.cpp \
 174     exports.cpp \
 175     exporthtmldialog.cpp \
 176     extrainfodialog.cpp \
 177     file.cpp \
 178     findwidget.cpp \
 179     findresultwidget.cpp \
 180     findresultitem.cpp \
 181     findresultmodel.cpp \
 182     flag.cpp \
 183     flagobj.cpp \
 184     flagrow.cpp \
 185     flagrowobj.cpp \
 186     floatimageobj.cpp \
 187     floatobj.cpp \
 188     frameobj.cpp \
 189     geometry.cpp \
 190     heading.cpp \
 191     headingeditor.cpp \
 192     headingobj.cpp \
 193     highlighter.cpp \
 194     historywindow.cpp \
 195     imageitem.cpp \
 196     imageobj.cpp \
 197     imports.cpp \
 198     lineeditdialog.cpp \
 199     linkablemapobj.cpp \
 200     lockedfiledialog.cpp \
 201     macros.cpp \
 202     main.cpp \
 203     mainwindow.cpp \
 204     mapeditor.cpp \
 205     mapitem.cpp \
 206     mapobj.cpp \
 207     misc.cpp \
 208     mysortfilterproxymodel.cpp \
 209     noteeditor.cpp \
 210     options.cpp \
 211     ornamentedobj.cpp \
 212     parser.cpp \
 213     scripteditor.cpp \
 214     settings.cpp \
 215     shortcuts.cpp\
 216     showtextdialog.cpp \
 217     slidecontrolwidget.cpp \
 218     slideeditor.cpp \
 219     slideitem.cpp \
 220     slidemodel.cpp \
 221     task.cpp \
 222     taskeditor.cpp \
 223     taskmodel.cpp \
 224     texteditor.cpp \
 225     treedelegate.cpp \
 226     treeeditor.cpp \
 227     treeitem.cpp \
 228     treemodel.cpp \
 229     version.cpp \
 230     vymlock.cpp \
 231     vymmodel.cpp \
 232     vymnote.cpp \
 233     vymprocess.cpp \
 234     vymtext.cpp \
 235     vymview.cpp \
 236     warningdialog.cpp \
 237     winter.cpp \
 238     xlink.cpp \
 239     xlinkitem.cpp \
 240     xlinkobj.cpp \
 241     xml-base.cpp \
 242     xml-vym.cpp \
 243     xml-freemind.cpp \
 244     xmlobj.cpp \
 245     xsltproc.cpp
 246
 247 FORMS = \
 248     attributewidget.ui \
 249     branchpropeditor.ui \
 250     exporthtmldialog.ui \
 251     extrainfodialog.ui \
 252     editxlinkdialog.ui \
 253     historywindow.ui \
 254     lineeditdialog.ui \
 255     lockedfiledialog.ui \
 256     scripteditor.ui \
 257     showtextdialog.ui \
 258     warningdialog.ui \
 259
 260 isEmpty( PREFIX ) {
 261     PREFIX = /usr/local
 262     count( INSTALLDIR, 1 ) {
 263         PREFIX = $${INSTALLDIR}
 264         message( "Please use PREFIX instead of INSTALLDIR" )
 265     }
 266 }
 267 isEmpty( BINDIR ) {
 268     BINDIR = $${PREFIX}/bin
 269 }
 270 isEmpty( DATADIR ) {
 271     DATADIR = $${PREFIX}
 272 }
 273
 274 message( "Installation directory" )
 275 message( $$PREFIX )
 276
 277
 278 target.path = $${BINDIR}
 279 INSTALLS += target
 280
 281 language.files = lang/*.qm
 282 language.path = $${DATADIR}/vym/lang
 283 INSTALLS += language
 284
 285 support.files = styles/ scripts/ icons/ flags/ macros/ exports/ demos/
 286 support.files += LICENSE.txt
 287 support.path = $${DATADIR}/vym
 288 INSTALLS += support
 289