SConstruct

   1 #
   2 #       SConstruct (10.09.09)
   3 #       SConscript for all components.
   4 #
   5 #       Copyright (C) 2009, 2010  Andrew Nayenko
   6 #
   7 #       This program is free software: you can redistribute it and/or modify
   8 #       it under the terms of the GNU General Public License as published by
   9 #       the Free Software Foundation, either version 3 of the License, or
  10 #       (at your option) any later version.
  11 #
  12 #       This program is distributed in the hope that it will be useful,
  13 #       but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #       MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #       GNU General Public License for more details.
  16 #
  17 #       You should have received a copy of the GNU General Public License
  18 #       along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21 import os
  22 import platform
  23 import SCons
  24
  25 env = Environment(**ARGUMENTS)
  26 conf = Configure(env)
  27
  28 destdir = env.get('DESTDIR', '/sbin');
  29 targets = []
  30 libs = ['exfat']
  31
  32 if 'CC' in os.environ:
  33         conf.env.Replace(CC = os.environ['CC'])
  34 if 'CCFLAGS' in os.environ:
  35         conf.env.Replace(CCFLAGS = os.environ['CCFLAGS'])
  36 # Set default CCFLAGS for known compilers
  37 if not conf.env['CCFLAGS']:
  38         if conf.env['CC'] == 'gcc':
  39                 conf.env.Replace(CCFLAGS = '-Wall -O2 -ggdb')
  40         elif conf.env['CC'] == 'clang':
  41                 conf.env.Replace(CCFLAGS = '-Wall -O2 -g')
  42 conf.env.Append(CPPDEFINES = {'FUSE_USE_VERSION': 26})
  43 conf.env.Append(CPPDEFINES = {'_FILE_OFFSET_BITS' : 64})
  44 conf.env.Append(CPPPATH = ['libexfat'])
  45 if 'LDFLAGS' in os.environ:
  46         conf.env.Append(LINKFLAGS = os.environ['LDFLAGS'])
  47 conf.env.Append(LIBPATH = ['libexfat'])
  48
  49 # __DARWIN_64_BIT_INO_T=0 define is needed because since Snow Leopard inode
  50 # numbers are 64-bit by default, but libfuse operates 32-bit ones. This define
  51 # forces 32-bit inode declaration in system headers, but it's also possible to
  52 # link against libfuse_ino64 instead.
  53 if platform.system() == 'Darwin':
  54         conf.env.Append(CPPDEFINES = {'__DARWIN_64_BIT_INO_T' : 0})
  55         conf.env.Append(CPPDEFINES = {'__DARWIN_UNIX03' : 1})
  56
  57 # FreeBSD does not support block devices, only raw devices. Ublio is required
  58 # for unaligned I/O and caching.
  59 if platform.system() == 'FreeBSD':
  60         conf.env.Append(CPPDEFINES = 'USE_UBLIO')
  61         libs.append('ublio')
  62         conf.env.Append(CPPPATH = ['/usr/local/include'])
  63         conf.env.Append(LIBPATH = ['/usr/local/lib'])
  64
  65 env = conf.Finish()
  66
  67 def make_symlink(dir, target, link_name):
  68         workdir = os.getcwd()
  69         os.chdir(dir)
  70         try:
  71                 os.remove(link_name)
  72         except OSError:
  73                 pass
  74         os.symlink(target, link_name)
  75         os.chdir(workdir)
  76
  77 symlink = SCons.Action.ActionFactory(make_symlink,
  78                 lambda dir, target, link_name:
  79                                 'make_symlink("%s", "%s", "%s")' % (dir, target, link_name))
  80
  81 def program(pattern, output, alias, libs):
  82         sources = Glob(pattern)
  83         if not sources:
  84                 return
  85         target = env.Program(output, sources, LIBS = libs)
  86         if alias:
  87                 Alias('install', Install(destdir, target),
  88                                 symlink(destdir, os.path.basename(output), alias))
  89         else:
  90                 Alias('install', Install(destdir, target))
  91         targets.append(target)
  92
  93 env.Library('libexfat/exfat', Glob('libexfat/*.c'))
  94
  95 program('fuse/*.c', 'fuse/mount.exfat-fuse', 'mount.exfat', [libs + ['fuse']])
  96 program('dump/*.c', 'dump/dumpexfat', None, libs)
  97 program('fsck/*.c', 'fsck/exfatfsck', 'fsck.exfat', libs)
  98 program('mkfs/*.c', 'mkfs/mkexfatfs', 'mkfs.exfat', libs)
  99 program('label/*.c', 'label/exfatlabel', None, libs)
 100
 101 Default(targets)